/*
 * Blink
 * Turns on an LED on for one second,
 * then off for one second, repeatedly.
 */
#include "Arduino.h"

#include <Wire.h>
#include <LiquidCrystal_I2C.h>

LiquidCrystal_I2C lcd(0x27, 2, 1, 0, 4, 5, 6, 7, 3, POSITIVE);

#define PIN_RESET 2
#define PIN_CAR1 3
#define PIN_LED LED_BUILTIN

typedef struct {
  // input pin for this car
  short pin;
  // elapsed time for pin (0 means not finished)
  unsigned int elapsedTime;
} Car;

// assume all cars are on sequential digital pins
#define PIN_CAR_STARTING 3

// number of cars (4 max)
#define CAR_COUNT 2

// array of cars
Car cars[CAR_COUNT];

// buffer for the LCD line
char buffer[40];

void setup()
{

  Serial.begin(9600);

  pinMode(PIN_RESET, INPUT_PULLUP);
  pinMode(LED_BUILTIN, OUTPUT);

  // initialize each car PIN
  for(short i=0; i<CAR_COUNT; i++) {
    cars[i].pin = PIN_CAR_STARTING + i;
    pinMode(cars[i].pin, INPUT_PULLUP);
  }

  // initialize LCD
  lcd.begin(20, 4);
  lcd.backlight();
  lcd.setCursor(1,1);
  lcd.print("Jeff's Inept");
  lcd.setCursor(6,2);
  lcd.print("Kub Kar Timer");
}

void resetCars() {
  for(short i=0; i<CAR_COUNT; i++) {
    cars[i].elapsedTime = 0;
  }
}

void displayTimers() {
  short row = 0;
  lcd.clear();

  // keep track of cars that we've already printed a score for
  bool seenCar[CAR_COUNT];
  for (int i=0; i<CAR_COUNT; i++) {
    seenCar[i] = false;
  }

  for(short place=0; place<CAR_COUNT; place++) {

    // find which is the fastest car that hasn't already been processed
    short currentCar = -1;
    for (short i=0; i<CAR_COUNT; i++) {
      if (!seenCar[i] && cars[i].elapsedTime != 0 && (currentCar == -1 || cars[i].elapsedTime < cars[currentCar].elapsedTime)) {
        currentCar = i;
      }
    }

    // mark car as seen so we don't show the same car again
    seenCar[currentCar] = true;

    if (cars[currentCar].elapsedTime != 0) {
      // only print the score if this car finished
      lcd.setCursor(0,row++);
      sprintf(buffer, "%d%s: CAR%d @ %0.2fs", place+1, place==0?"st":(place==1?"nd":(place==2?"rd":"th")) , currentCar+1, cars[currentCar].elapsedTime/1000.0);
      lcd.print(buffer);
    }
  }
}

#define MAX_TIME 5000

unsigned long startTime;         // start time in ms

#define STATE_READY 1
#define STATE_RUNNING 2
#define STATE_DONE 3

short state = 0;

void loop()
{

  if (digitalRead(PIN_RESET) == LOW) {
    if (state != STATE_READY) {
      state = STATE_READY;
      lcd.clear();
      lcd.setCursor(0,0);
      lcd.print("Ready...");
      resetCars();
      digitalWrite(PIN_LED, HIGH);
    }
  } else {
    if (state == STATE_READY) {
      digitalWrite(PIN_LED, LOW);
      state = STATE_RUNNING;
      lcd.setCursor(0,0);
      lcd.print("Running!");
      startTime = millis();
    }
    if (state == STATE_RUNNING) {

      // calculate elapsed time in ms
      unsigned long elapsedTime = millis() - startTime;

      bool allDone = true;
      for(short i = 0; i<CAR_COUNT; i++) {
        if (cars[i].elapsedTime == 0) {
          if (digitalRead(cars[i].pin) == LOW) {
            // car finished, record time
            cars[i].elapsedTime = elapsedTime;
          } else {
            allDone = false;
          }
        }
      }

      // stop race if all cars are done or MAX TIME exceeded
      if (allDone || elapsedTime > MAX_TIME) {
        state = STATE_DONE;
        displayTimers();
      }

    }

  }

}